#7：ParaSpace事件：与时间赛跑，挫败行业迄今最严重的攻击

背景

2023 年 3 月 17 日，NFT 借贷平台 Paraspace（现为 Parallel Finance）因其价格预言机存在漏洞而遭到严重攻击。Paraspace 允许用户存入 NFT 和 ERC-20 代币作为抵押品来借出 ERC-20 代币，从而在不卖出 NFT 的前提下获得收益。

ParaSpace 的一个核心功能是 ApeStaking，它可以自动复投 APE 奖励。质押 APE 的用户会收到 cAPE 代币（APE 的 cToken 表示形式），这些代币可用作抵押品来借入 USDC 和 WETH 等资产。存入 cAPE 代币会获得 pcAPE 份额，其抵押价值通过 pcAPE 金额乘以其 rebasingIndex（重定基数指数）计算得出。

rebasingIndex 是从总池化 APE 余额和总份额中推导出来的，如下面的代码片段所示：

function _scaledBalanceOf(address user, uint256 rebasingIndex)
    internal
    view
    returns (uint256)
{
    return super.scaledBalanceOf(user).rayMul(rebasingIndex);
}

function lastRebasingIndex() internal view override returns (uint256) {
  return ICApe(_underlyingAsset).getPooledApeByShares(WadRayMath.RAY);
}

function getPooledApeByShares(uint256 sharesAmount)
    public
    view
    returns (uint256)
{
    uint256 totalShares = _getTotalShares();
    if (totalShares == 0) {
        return 0;
    } else {
        return
            sharesAmount.mul(_getTotalPooledApeBalance()).div(totalShares);
    }
}

function _getTotalPooledApeBalance()
    internal
    view
    override
    returns (uint256)
{
    (uint256 stakedAmount, ) = apeStaking.addressPosition(address(this));
    uint256 rewardAmount = apeStaking.pendingRewards(
        APE_COIN_POOL_ID,
        address(this),
        0
    );
    return stakedAmount + rewardAmount + bufferBalance;
}

_getTotalPooledApeBalance() 函数汇总了 ApeCoinStaking 合约中的已质押 APE 代币、待领取奖励以及缓冲余额。

漏洞分析

漏洞在于对 rebasingIndex 的操纵，这人为地夸大了 cAPE 代币的抵押价值。具体来说，ApeCoinStaking 合约中的 depositApeCoin() 函数会增加仓位的 stakedAmount。攻击者可以通过将 APE 代币存入 cAPE 仓位来利用这一点，从而夸大 _getTotalPooledApeBalance() 的输出结果，进而影响 rebasingIndex。

function depositApeCoin(uint256 _amount, address _recipient) public {
    if (_amount < MIN_DEPOSIT) revert DepositMoreThanOneAPE();
    updatePool(APECOIN_POOL_ID);

    Position storage position = addressPosition[_recipient];
    _deposit(APECOIN_POOL_ID, position, _amount);

    apeCoin.transferFrom(msg.sender, address(this), _amount);

    emit Deposit(msg.sender, _amount, _recipient);
}

function _deposit(uint256 _poolId, Position storage _position, uint256 _amount) private {
  Pool storage pool = pools[_poolId];
  _position.stakedAmount += _amount;
  pool.stakedAmount += _amount.toUint96();
  _position.rewardsDebt += (_amount * pool.accumulatedRewardsPerShare).toInt256();
}

这一设计缺陷允许攻击者通过以 cAPE 为接收方调用 depositApeCoin() 存入 APE 代币，从而夸大抵押价值。

攻击分析

攻击者通过闪电贷攻击利用了该漏洞，主要步骤如下：

获得约 47,352 枚 wstETH 的闪电贷，并供应了约 46,018 枚 wstETH，通过多个合约借出 cAPE。
存入约 12,880,000 枚 cAPE 代币作为抵押品。
将约 1,205 枚 wstETH 兑换为约 492,124 枚 APE 代币，并将 1,839,999 枚 cAPE 提取为 APE 代币。
调用 ApeCoinStaking.depositApeCoin() 将 2,332,214 枚 APE 代币存入 cAPE 仓位，使协议的 stakedAmount 从 851,662 增加到 3,183,876（增长了 373%）。
利用夸大的抵押价值大额借入 USDC 和 WETH 等资产以获利。

这种通过闪电贷操纵 pcAPE 价格的行为，利用了预言机计算中使用现货价格的缺陷。